[NEWSboard IBMi Forum]
  1. #1
    Registriert seit
    Jun 2015
    Beiträge
    122

    Werte aus XML-Dateien mit RPG rauslesen (Verständnisfrage)

    Hallo zusammen,
    leider habe ich bisher noch nix mit dem o..a. Thema zu tun gehabt. Mittlerweile habe ich mal ein bisschen rumgesucht und etwas mehr Klarheit gewonnen. Aber auch nur ein wenig,

    Bitte mal das folgende XML-File ansehen:

    <?xml version="1.0" encoding="UTF-8"?>
    <SHARK-ERP>
    <Order>
    <OrderNumber>12345678</OrderNumber>
    <OrderTypeID>KA</OrderTypeID>
    <OrderLine>
    <LineNumber>1</LineNumber>
    <ArticleNumber>4712</ArticleNumber>
    <Qty>12</Qty>
    </OrderLine>
    </OrderLine>
    <LineNumber>2</LineNumber>
    <ArticleNumber>4713</ArticleNumber>
    <Qty>5</Qty>
    </OrderLine>
    </Order>
    </SHARK-ERP>

    Will ich nun z.B. die ORDERNUMBER rauslesen will, so kann ich das ja mit
    XML-into in ein normales Feld tun. Klappt auch bei mir.

    Wenn ich jetzt dann noch die Daten die zu ORDERLINE gehören mit auslesen will (evtl. mehrfach vorhanden), muss ich doch dann einen zweiten XML-into absetzen und das Ergebnis in eine Tabelle schreiben.

    Und jetzt meine Frage: Ist die Vorgehensweise so ok, oder kann man das auch alles in
    einem Aufwasch (ein XML-into) erledigen.

    Für Infos bin ich wie immer dankbar.

    Gruss A.

  2. #2
    Registriert seit
    Feb 2001
    Beiträge
    17.641
    Nein!
    Du kannst alles mit einem XML-Into bis zur letzten Ebene einlesen und bearbeiten.
    Dazu muss man mit Qualified-DS'n arbeiten, so dass man anschließend XML-ähnliche Strukturen verwenden kann:

    Konten1.Knoten2.Attribute1

    Auch Arrays lassen sich da locker befüllen.
    Nur muss man halt die Strukturen einzeln (buttom up) definieren.

    D OrderLine DS qualified template
    D LineNumber ...
    D ArticelNumber...

    D Order DS qualified template
    D OrderNumber ...
    D OrderTypeID ...
    D OrderLine likeds(OrderLine) dim(10)
    D OrderLineCnt 10I 0

    D SHARK_ERP DS qualified
    D Order Likeds(Order)

    Beim XML-Into gibt es dann nur ein Ziel mit den Zusatzoptionen, dass
    - nicht alle Strukturen da sein müssen
    - Namensersetzungen stattfinden (unbekannte Zeichen werden alle zu "_")
    - Bzgl. des CNT-Eintrages gibt es eine Namensregel (Beispiel im Handbuch). Da steht dann automatisch die Anzahl der geladenen Zeilen drin.

    Somit hast du dann Zugriff auf
    SHARK_ERP.Order.OrderNumber
    SHARK_ERP.Order.OrderLine(1).LineNumber

    usw.
    Dienstleistungen? Die gibt es hier: http://www.fuerchau.de
    Das Excel-AddIn: http://www.fuerchau.de/software/upload400.htm
    BI? Da war doch noch was: http://www.ftsolutions.de

  3. #3
    Registriert seit
    Jun 2015
    Beiträge
    122
    ok vielen Dank schon mal. Ich probiere das aus.
    Gruss A.

  4. #4
    Registriert seit
    Jun 2015
    Beiträge
    122
    Hallo Fuerchau,
    ich komme mit dem XML-INTO - Aufruf nicht klar, sodass ich alle XML-Elemente erwische. Könntest Du mir da bitte nochmals helfen. Wie sähe der Aufruf dann aus ?
    Vielen Dank schon mal, Gruss A.

  5. #5
    Registriert seit
    Feb 2001
    Beiträge
    17.641
    Ich bin da demnächst mal auf dem Kundensystem und zeige davon dann mein Beispiel.
    So (Auszüge):

    Code:
    d* Datum-Referenz                                           
    dC_C507           ds                  qualified template    
    d D_2380                        20    varying               
    
    dS_DTM            ds                  qualified template    
    d C_C507                              likeds(C_C507)        
    
    d* Preise                                                     
    dC_C509           ds                  qualified template      
    d D_5125                        10    varying                 
    d D_5118                        15    varying                 
    d D_5375                        10    varying                 
    d D_5378                        10    varying                 
    d D_5284                        10    varying                 
    d D_6411                        10    varying                 
    
    dS_PRI            ds                  qualified template    
    d C_C509                              likeds(C_C509)        
    
    dG_LIN_PRI        ds                  qualified template     
    d S_PRI                               likeds(S_PRI)          
    d S_DTM                               likeds(S_DTM) dim(2)   
    d cntS_DTM                      10i 0                        
    
    dG_LIN            ds                  qualified template            
    d S_LIN                               likeds(S_LIN)                 
    d S_IMD                               likeds(S_IMD)     dim(2)      
    D G_LIN_PRI                           likeds(G_LIN_PRI) dim(2)      
    
    d* Gesamtdokument                                              
    dXMLFACT_ORDERS   ds                  qualified                
    d S_IMD                               likeds(S_IMD)            
    d G_LIN                               likeds(G_LIN) dim(999)   
    d cntG_LIN                      10i 0                          
    
    d G_LINi          s              5i 0   
    
    dXMLName          s            256    varying inz    
    dXMLOption        s            256    varying inz    
    
    // Festlegen der XML-Optionen                                                      
    XMLOption = ' trim=all'                 // Leerzeichen am Anfang/Ende              
              + ' allowmissing=yes'         // fehlende Knoten ignorieren              
              + ' allowextra=yes'           // zusätzliche Knoten ignorieren           
              + ' countprefix=cnt'          // Zählervariable für Arrays               
              + ' case=convert'             // ungültige Zeichen in "_" konvertieren   
              + ' doc=file'                 // XML aus Datei lesen                     
              ;                                                                        
    
    XMLName = XMLPath + %trim(XMLOName); // Kompletter Pfadname         
    XML-INTO XMLFACT_ORDERS %xml(XMLName : XMLOption); 
    
    for G_LINi = 1 to XMLFACT_ORDERS.cntG_LIN;                     
        if XMLFACT_ORDERS.G_LIN(G_LINi)                            
           .S_LIN.C_C212.D_7140 <> *blank;   // mit Sachnummer     
    :
    : 
       endif;
    endfor;
    Analog musst du also ebenso deine XML-Struktur rekursiv aufbauen und mittels geschachteltem likeds() zusammenbauen.
    Aus Sicherheitsgründen definiere ich alles als Zeichenfelder um dann Zahl-/Datumswerte per individueller Konvertierung %date(), %dec() zu erhalten.
    Dienstleistungen? Die gibt es hier: http://www.fuerchau.de
    Das Excel-AddIn: http://www.fuerchau.de/software/upload400.htm
    BI? Da war doch noch was: http://www.ftsolutions.de

Ähnliche Themen

  1. SQL - Verständnisfrage
    Von nico1964 im Forum NEWSboard programmierung
    Antworten: 4
    Letzter Beitrag: 13-09-18, 09:54
  2. Sql Null Werte
    Von tarkusch im Forum NEWSboard programmierung
    Antworten: 11
    Letzter Beitrag: 26-07-17, 09:12
  3. Werte vergleichen
    Von FNeurieser im Forum NEWSboard programmierung
    Antworten: 8
    Letzter Beitrag: 07-07-16, 21:35
  4. Performance Werte V5R4
    Von KingofKning im Forum System i Hauptforum
    Antworten: 9
    Letzter Beitrag: 07-07-14, 14:15
  5. Query 0-Werte Ausgeben???
    Von qiwi2000 im Forum System i Hauptforum
    Antworten: 5
    Letzter Beitrag: 26-04-02, 07:51

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •