Abbildung 3
Program FTPTFRR

      *=====================================================================
      *  = Programm . . .  FTPTFRR   
      *  = Beschreibung .  FTP-Anweisungen generieren      
      *=====================================================================

(A)  FFTP_SrcDat O  A E             Disk    Rename( FTP_SrcDat : SrcRcd )

      *=====================================================================
      *  Aufrufparameter
      *=====================================================================
(B)  D AufrufParm      PR                  ExtPgm( 'FTPTFRR' )
     D                               10
     D                               50
     D                               20
     D                               20
     D AufrufParm      PI
     D  A#UsrPrf                     10
     D  A#Kennwort                   50
     D  QuellDatIn                   20
     D  ZielDatIn                    20

      *=====================================================================
      *  Felddefinitionen
      *=====================================================================
(C)  D QuellDat_q    DS
     D  QuellDat                     10
     D  QuellBib                     10

     D ZielDat_q      DS
     D  ZielDat                      10
     D  ZielBib                      10

      *=====================================================================
      *  FTP-Anweisungen in temporäre Teildatei schreiben
      *=====================================================================
     C                   Eval      QuellDat_q = QuellDatIn
     C                   Eval      ZielDat_q   = ZielDatIn

      *  FTP-Anweisung: Benutzer + Kennwort
     C                   Eval      SrcSeq = SrcSeq + 1

(D)  C                   Eval      SrcDta = A#UsrPrf   +
     C                                      ' '        +
     C                                      A#Kennwort
     C                   Write     SrcRcd

      *  FTP-Anweisung: PUT-Anweisung
     C                   Eval      SrcSeq = SrcSeq + 1

(E)  C                   Eval      SrcDta = 'Put '               +
     C                                      %Trim( QuellBib )    +
     C                                      '/'                  +
     C                                      %Trim( QuellDat )    +
     C                                      ' '                  +
     C                                      %Trim( ZielBib )     +
     C                                      '/'                  +
     C                                      %Trim( ZielDat )
     C                   Write     SrcRcd

      *  FTP-Anweisung: QUIT
     C                   Eval      SrcSeq = SrcSeq + 1
     C                   Eval      SrcDta = 'Quit '
     C                   Write     SrcRcd

      *=====================================================================
      *  Programmende
     C                   Eval      *InLR = *On
      *=====================================================================