Hallo,

in der iNN - eNews 7/2006 (www.iNN-Online.de) war die Prozedur, die Du benötigst.

Hier nochmals:
PHP-Code:
H NoMain
 *-------------------------------------------------------------------------
D/Copy QPROLESRC/DateFkt
D YearWeekIso     PR             6S 0    
D   ParmDate                      D      
 **************************************************************************
P* Procedure name:  YearWeekIso                                   
P* Purpose:         Ermitteln Jahr + Kalenderwoche aus Datum      
P* Returns:         YYYYKW  (6S 0)                                
P* Parameter:       ParmDate   => Datum                           
 **************************************************************************
P YearWeekIso     B                   Export                      
D YearWeekIso     PI             6S 0                             
D   ParmDate                      D                               
                                                                  
D DsYearWeek      DS                                              
D   YearWeek                     6S 0                             
D   DsYear                       4S 0 Overlay(YearWeek)           
D   DsWeek                       2S 0 Overlay(YearWeek: *Next)    
 *-------------------------------------------------------------------------
C/EXEC SQL   Set Option DatFmt = *ISO, TimFmt = *ISO              
C/END-EXEC                                                        
                                                                  
C/EXEC SQL   Set :DSWeek = Week_ISO(:ParmDate)                    
C/END-EXEC 
                                                       
C/EXEC SQL                                                         
C+ Set :DSYear = Case When Month(:ParmDate) = 12 and :DsWeek  =  1 
C+                    Then Year(:ParmDate)  +  1                     
C+                    When Month(:ParmDate) =  1 and :DSWeek >= 52 
C+                    Then Year(:ParmDate)  -  1                     
C+                    Else Year(:ParmDate)                         
C+               End                                               
C/END-EXEC                                                         
C                   Return    YearWeek                              
P YearWeekIso     E 
Birgitta