Relativ Einfach :

1. DDS-DSPF
Code:
A                                      DSPSIZ(24 80 *DS3         
A                                             27 132 *DS4)       

A          R CHKDS4S4                                            
A                                      DSPMOD(*DS4)              
A                                  1  3' '
2. RPG-Code
Code:
H              J                                                   
F* --------------------------------------------------------------- 
F* PRÜFEN OB DER VERWENDETE BILDSCHIRM *DS4 FÄHIG IST.             
F*                                                                 
F* FALLS EINE *DS4-ANZEIGE MÖGLICH IST,                            
F* WIRD DER ÜBERGABEPARAMTER MIT EINEM 'J' GEFÜLLT.                
F* ANSONSTEN IST DER RETURNCODE MIT    'N' GEFÜLLT.                
F* --------------------------------------------------------------- 
F*                                                                 
FCHKDS4  CF  E                    WORKSTN                          
F                                              KINFDS PRUEF        
F*                                                                 
IPRUEF       DS                                                    
I                                       67  70 SPZE                
I                                      273 282 EINH                
C*
C           *ENTRY    PLIST                          
C                     PARM           RETURN  1       
C*                                                   
C                     MOVE 'N'       RETURN          
C*
C                     WRITECHKDS4S4             
C           EINH      POST           PRUEF      
C           SPZE      IFEQ '3564'               
C                     MOVE 'J'       RETURN     
C                     END
C*  DUMMY WEGEN RPG-COMPILER             
C                     GOTO WEITER        
C                     EXFMTCHKDS4S4      
C           WEITER    TAG                
C*                                        
C                     RETRN
Hintergrund :
In der INFDS zum DSPF steht im Bereich 67-70 (nach einer POST-Operation) die aktuelle Bildschirmgröße.
Wenn an einem nicht 132-spaltenfähigen Bildschirm versucht wird nach *DS4 umzuschalten, steht weiterhin '1920' (80 x 24) als Bildschirmgröße sonst '3564' (132 x 27)

Sven


[Dieser Beitrag wurde von Sven Schneider am 22. Juli 2002 editiert.]