Zitat Zitat von mic74 Beitrag anzeigen
Kann ich im CL einen TFRJOB JOBQ(QCTL) hinterlegen damit der Job im QCTL weiterläuft, wenn ich die Subsysteme beende ?
Warum so umständlich? Submitte einfach:

SBMJOB CMD(CALL QGPL/SAVEBCH)) JOBQ(QCTL)

Und hier SAVEBCH: (vorsicht, aus dem Schädel)

Code:
PGM                                                                   
                                                                      
             DCL        VAR(&ZAHL) TYPE(*DEC) LEN(1)                  
                                                                      
             MONMSG     MSGID(CPF0000)                                
             CHGJOB     LOG(4 00 *SECLVL) LOGCLPGM(*YES) +            
                          LOGOUTPUT(*JOBEND)                          
                                                                      
             CHGVAR     VAR(&ZAHL) VALUE(5)                           
                                                                      
             ENDSBS     SBS(*ALL) OPTION(*IMMED) BCHTIMLMT(180)       
             DLYJOB     DLY(120)                                      
             ENDSBS     SBS(*ALL) OPTION(*IMMED) BCHTIMLMT(180)       
             DLYJOB     DLY(120)                                      
                                                                      
             INZTAP     DEV(TAP01) NEWVOL(SAVE21) CHECK(*NO) +        
                          DENSITY(*CTGTYPE)                        
SAVESYS:                                                           
             SAVSYS     DEV(TAP01) ENDOPT(*LEAVE)                  
             MONMSG     MSGID(CPF3785) EXEC(DO)                    
             CHGVAR     VAR(&ZAHL) VALUE(&ZAHL - 1)                
             IF         COND(&ZAHL *EQ 0) THEN(GOTO CMDLBL(ENDABN))
             GOTO       CMDLBL(SAVESYS)                            
             ENDDO                                                 
                                                                   
                                                                   
            SAVLIB     LIB(*NONSYS) DEV(TAP01) ENDOPT(*LEAVE) +    
                         ACCPTH(*YES)                              
            SAVDLO     DLO(*ALL) DEV(TAP01) ENDOPT(*LEAVE)         
            SAV        DEV('/qsys.lib/tap01.devd') OBJ(('/*') +    
                         ('/QDLS' *OMIT) ('/QSYS.LIB' *OMIT))      
            CHKTAP     DEV(TAP01) ENDOPT(*REWIND)                  
            DSPTAP     DEV(TAP01) DATA(*SAVRST) OUTPUT(*PRINT)     
            STRSBS     SBSD(QCTL)                                  
            GOTO       CMDLBL(ENDE)                                
                                                                    
ENDABN:                                                             
             SNDMSG     MSG('Problem beim SAVSYS!') TOUSR(QSYSOPR)  
ENDE:                                                               
ENDPGM
Viel Spass!

Holger