DSPATR(PC) falsch

[Robi]

Hi *all
kann mir jemand sagen warum hier DSPATR(PC) nicht geht

DSPF

***************** Datenanfang ****************************************************
     A*%%TS  SD  20090522  131149  QPGMR4      REL-V5R4M0  5722-WDS               
     A*%%EC                                                                       
     A                                      DSPSIZ(24 80 *DS3   +                 
     A                                             27 132 *DS4)                   
     A                                      CF01                                  
     A                                      CF03                                  
     A          R FRAGER                                                          
     A*%%TS  SD  20090522  094506  QPGMR4      REL-V5R4M0  5722-WDS               
     A                                      WINDOW(&##WL01 &##WP01 5 50)          
     A                                      OVERLAY                               
     A                                      PROTECT                               
     A                                      PUTOVR                                
     A                                      KEEP                                  
              
     A                                      WDWBORDER((*COLOR BLU) (*DSPATR RI)-  
     A                                       (*CHAR '        '))                  
     A N90                                  WDWTITLE((*TEXT &$1HDRW) (*COLOR BL-  
     A                                      U) (*DSPATR RI) *CENTER)
     A  90                                  WDWTITLE((*TEXT &$1HDRW) (*COLOR RE-
     A                                      D) (*DSPATR RI) *CENTER)            
     A                                      WDWTITLE((*TEXT &$1FTAS) (*COLOR BL-
     A                                      U) (*DSPATR RI) *CENTER *BOTTOM)    
     A                                      CHANGE(60)                          
                                            
     A            ##WL01         2S 0P                                          
     A            ##WP01         3S 0P                                          
     A            $1HDRW        47A  P                                          
     A            $1FTAS        47A  P                                          
     A            FRAGE1        50   O  1  1DSPATR(HI)                          
     A                                      OVRDTA                              
     A            FRAGE2        50   O  2  1DSPATR(HI)                          
     A                                      OVRDTA                              
     A            ANTWORT1      50A  B  3  1DSPATR(UL)                          
     A                                      CHECK(LC)                           
     A  21N22                               DSPATR(PC)     
     A                                      OVRDTA         
     A            FRAGE3        39   O  4  1DSPATR(HI)     
     A  10        ANTWORT1A      1A  B  4 41DSPATR(UL)     
     A  22 10                               DSPATR(PC)     
     A  11        ANTWORT3A      3A  B  4 41DSPATR(UL)     
     A  22 11                               DSPATR(PC)     
     A  12        ANTWORT10     10A  B  4 41DSPATR(UL)     
     A  22 12                               DSPATR(PC)     
     A          R S99WIN                    ASSUME         
     A                                      OVERLAY        
     A                                  1  2' '

Das 1. DSPATR(PC) ist eigendlich nur auf 21,
die anderen nur auf 22

bei exfmt ist 21 aus, 22 und 10 an.
Cursor steht aber auf ANTWORT1

Das macht mich irre, hilfe

Danke,
Robi

[Fuerchau]

PUTOVR und OVRDTA stören da.

Diese Attribute waren mal früher bei langsamen Terminals nötig.

Bei der 1. Ausgabe wird das gesamte Format ausgegeben.
Bei jeder erneuten Ausgabe werden nur die Felder ausgegeben, deren OVRDTA und OVRATR aktiv sind, also über Bezugszahlen an sind.

Da du OVRATR nicht verwendest, werden eben nur noch die Felder mit OVRDTA übertragen.
ALLES ANDERE NICHT !

Entferne PUTOVR und OVRDTA.

[Robi]

Wunderbar, das wars.
Diese Schlüsselwörter sind in fast allen DSPF's ...und durch kopieren reingekommen. Gedanken über ihre bedeutung hab ich mir noch nie gemacht ...

Danke
schönes WE
Robi