Zugriff auf PC mit User/Passwort

[KingofKning]

@KingofKning
Hab keinen zugriff auf den PC

jedenfals nicht um dort irgend etwas zu installieren.

Na ja, wollen die nicht oder können die nicht oder gehts aus Prinzip nicht?!
Das heißt der PC gehört einem Kunden? Ohne sein zutun wirds schwierig.

Habe das noch in meinem Fundus, aber nie ausprobiert.

/*-----------------------------------------------------------------S*/
/* */
/* Achtung: Programm als Sicherheitsbeauftragter erstellen !!!! */
/* (... mit USER(*OWNER) ... */
/* */
/* -----------------------------------------------------------*/
/* CALL <--: ./. */
/* CALL -->: ./. */
/* SAPMOUNTC MOUNT/UNMOUNT FILE-SYSTEM AUF UNIX-ANLAGE */
/*------------------------------------------------------------------*/
/*------------------------------------------------------------------*/
/* FUNCTION: Mit diesem Programm wird das UNIX File-System */
/* je nach Option entweder an- oder abgehängt. */
/* Als Parameter werden weiterhin der Name des */
/* fernen Systems (TCP/IP Host-Tabelle pflegen), */
/* der Name des fernen Dateisystems sowie der */
/* der Name des lokalen Dateisystems, das dabei */
/* überlagert werden soll. */
/* */
/* Vorausssetzungen: */
/* 1.) im QSTRUPPGM (Start-PGM nach IPL) muss STRNFSSVR *ALL stehen */
/* 2.) In der HOST-Tabelle der AS/400 muss der Eintrag des fernen */
/* System stehen (Befehl CFGTCP, Auswahl 10) */
/* 3.) Zwischen den Plattformen muss eine USER-ID vereinbart */
/* werden: Auf Unix ist das die UID (eine Zahl als User-ID); */
/* dafür muss auf der AS/400 ein Benutzerprofil erstellt */
/* werden, der im Schlüsselwort UID genau diese Nummer enthält. */
/* Gegebenenfalls kann eine Benutzergruppe (GID) in Betracht */
/* gezogen werden. Mit WRKLNK, Auswahl 9 kann die Berechtigung */
/* auf der AS/400 eingepflegt werden (oder CHGAUT) */
/* 4.) Die Gegenstation muss ihrerseits das Verzeichnis exportieren */
/* Auf der AS/400 heisst der äquivalente Befehl CHGNFSEXP */
/* */
/* Beispiel: */
/* OPTION '1' oder '0' --> an- bzw. abhängen */
/* RMTSYS SSID0003 --> fernes System heisst SSID0003 */
/* */
/* Achtung: SSID0003 mit CFGTCP, Auswahl 10 Host-Tabellen pflegen */
/* */
/* RMTFILESYS /komm --> ab fernen Pfad anhängen */
/* MNTOVRDIR /komm --> über den lokalen Pfad /komm */
/* */
/* -----------------------------------------------------------*/
/* CALL <--: ./. */
/* CALL -->: ./. */
/* -----------------------------------------------------------*/
/* DESCRIPT: ...... */
/* */
/* -----------------------------------------------------------*/
/*------------------------------------------------------------------*/
/* erstellt: TT.MM.JJ von: ........... V.00 PA: ...NN */
/* geändert: TT.MM.JJ von: ........... V.-- PA: ..... */
/*-----------------------------------------------------------------E*/
/*--*/
PGM PARM(&OPTION &RMTSYS &RMTFILSYS &MNTOVRDIR)
/*--*/
/*------------------------------------------------------------------*/
/* DECL VARIABLE.. TYPE. LENGTH.... +VALUE.......... */
/*------------------------------------------------------------------*/
/*--*/
/* Deklarieren der Parametervariablen */
DCL VAR(&OPTION) TYPE(*CHAR) LEN(1) /* Option: +
1=MOUNT (Anhängen); 0=UNMOUNT (Abhängen) */
DCL VAR(&RMTSYS) TYPE(*CHAR) LEN(255) /* Name +
des fernen Systems; in Host-Tabelle +
definieren */
DCL VAR(&RMTFILSYS) TYPE(*CHAR) LEN(64) /* +
Dateiverzeichnis des fernen Systems */
DCL VAR(&MNTOVRDIR) TYPE(*CHAR) LEN(64) /* +
Dateiverzeichnis des fernen Systems */
/*--*/
/* Deklarieren der Programmvariablen */
DCL VAR(&MFS) TYPE(*CHAR) LEN(640)
/*--*/
/* Deklarieren der Variablen zur Fehlerbehebung */
/*--*/
DCL VAR(&ERRBYTES) TYPE(*CHAR) LEN(4) +
VALUE(X'00000000')
DCL VAR(&ERROR) TYPE(*LGL) VALUE('0')
DCL VAR(&MSGKEY) TYPE(*CHAR) LEN(4)
DCL VAR(&MSGTYP) TYPE(*CHAR) LEN(10) +
VALUE('*DIAG ')
DCL VAR(&MSGTYPCTR) TYPE(*CHAR) LEN(4) +
VALUE(X'00000001')
DCL VAR(&PGMMSGQ) TYPE(*CHAR) LEN(10) VALUE('*')
DCL VAR(&STKCTR) TYPE(*CHAR) LEN(4) +
VALUE(X'00000001')
/*--*/
/* Deklarieren der Datei, falls erforderlich */
/*--*/
/* Globale Fehlerüberwachung (Standard) */
/*--*/
MONMSG MSGID(CPF0000) EXEC(GOTO CMDLBL(ERRPROC))
/*--*/
/*------------------------------------------------------------------*/
/* Ab hier erfolgt das eigentliche Programm */
/*------------------------------------------------------------------*/
/*--*/
/*------------------------------------------------------------------*/
/* 1. Fall: Anhängen wird angefordert OPTION = '1' */
/*------------------------------------------------------------------*/
IF COND(&OPTION = '1') THEN(DO)
CHGVAR VAR(&MFS) VALUE(&RMTSYS *TCAT ':' *CAT +
&RMTFILSYS)
MOUNT TYPE(*NFS) MFS(&MFS) MNTOVRDIR(&MNTOVRDIR) +
/* File System wird angehängt */
ENDDO
/*--*/
/*------------------------------------------------------------------*/
/* 2. Fall: Abhängen wird angefordert OPTION = '0' */
/*------------------------------------------------------------------*/
IF COND(&OPTION = '0') THEN(DO)
CHGVAR VAR(&MFS) VALUE(&RMTSYS *TCAT ':' *CAT +
&RMTFILSYS)
UNMOUNT TYPE(*NFS) MNTOVRDIR(&MNTOVRDIR) /* File +
System wird abgehängt */
ENDDO
/*--*/
/*------------------------------------------------------------------*/
/* Ende des eigentlichen Programms */
/*------------------------------------------------------------------*/
/*--*/
/* Beendigungsnachrichten von hier aus senden */
/*--*/
RETURN
/*--*/
/*--*/
/*------------------------------------------------------------------*/
/* Fehlerbehandlungsroutine */
/*------------------------------------------------------------------*/
/*--*/
ERRPROC: IF COND(&ERROR) THEN(GOTO CMDLBL(ERRDONE))
ELSE CMD(CHGVAR VAR(&ERROR) VALUE('1'))
/*--*/
/* Alle *DIAG-Nachrichten an das aufrufende Programm übertragen */
/*--*/
CALL PGM(QMHMOVPM) PARM(&MSGKEY &MSGTYP +
&MSGTYPCTR &PGMMSGQ &STKCTR &ERRBYTES)
/*--*/
/* Letzte *ESCAPE-Nachricht weiterleiten */
/*--*/
ERRDONE: CALL PGM(QMHRSNEM) PARM(&MSGKEY &ERRBYTES)
MONMSG MSGID(CPF0000) EXEC(DO)
SNDPGMMSG MSGID(CPF3CF2) MSGF(QCPFMSG) +
MSGDTA('QMHRSNEM') MSGTYPE(*ESCAPE)
MONMSG MSGID(CPF0000)
ENDDO
/*--*/
ENDPGM
/*------------------------------------------------------------------*/

Vielleicht mal nach gurgeln, gibt evtl noch mehr Infos dazu
GG