CPYTOIMPF Datensalat

[Mr-Ferret]

Hallo,
ich habe ein kleines Problem mit dem CPYTOIMPF, ich setzte folgendes Statement ab:

CPYTOIMPF FROMFILE(OUTQMK/TEXTFILE) TOSTMF('/home/MKLEIN/meinedat.txt') STMFCODPAG(*STDASCII) STMFAUT(*FILE) RCDDLM(*CRLF) DTAFMT(*FIXED)

dabei erfolgt auch eine Datenübertragung ins IFS :-)
Jedoch das Ergebnis ist nicht das was ich erwartet habe :-(
Das sieht dann so aus:

@õ÷÷ðââñ@å÷ÙñÔð@ñððôòó@@@@@@@@@ @@@@@@@@@æ–™’@¦‰£ˆ@Áƒ£‰¥…@Ñ� �‚¢@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@ôañõa ñö@@øzððzðð@@@@@@@@ׁ‡…@@@@ñ@@
@Ù…¢…£@K@K@K@K@K@K@K@K@K@K@K@K@K@K@K@K@K@z@ @@\ÕÖ@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@


Wenn ich die ursprünglich Tabelle mir mit SQL ansehe, ist alles so wie es sein soll, aber nach der Übertragung ins IFS .......

Was stimmt an dem CPYTOIMPF Statement nicht?

Vielen Dank für eure Hilfe!

Gruß
Manfred

[TheDevil]

Hallo.

Nehm mal bitte : STMFCODPAG(*PCASCII)

Gruß,
Ralf

[Fuerchau]

Jedwede ASCII-Tabelle ist grundsätzlich falsch wenn man nicht mit DOS umgeht.
1252 (ANSI-Westeuropa) wäre wohl besser geeignet.
Wenn die Zieldatei aber existiert, wird die dort bereits angegebene CCSID genommen.
Also besser das Ziel erst mal löschen.

[Mr-Ferret]

Danke für die schnellen Antworten,
jedoch habe ich schon STMFCODPAG(*PCASCII) versucht und die Zieldatei ebenfalls gelöscht.

Es muss doch an der Ursprungsdatei liegen, ich habe das mit einer anderen Datei getestet, und da ist alles so wie es soll.

Aber vielleicht gibt es eine andere Lösung?!
Ich mache folgenes:
Jeden Tag um 18:00 und 06:00 Uhr läuft ein Job der die Ausgabe von WRKSYSSTS in eine Outputq schreibt.
WRKSYSSTS OUTPUT(*PRINT) ASTLVL(*BASIC)

Dort steht auch drin wie die aktuelle Plattenauslastung ist. Diese Zahl wird dann in eine Mysql DB eingetragen und mit PHP, CSS und HTML eine Grafik erstellt.
Wenn ich also diesen Wert in das IFS bekomme, kann ich den Rest auch automatisieren so das die Grafik immer aktuell ist.
Ich wollte also die Ausgabe mit CPYTOIMPF ins IFS haben und diese dann mit Java auslesen und in die DB eintragen. O.K. Java hab ich kein Ahnung, das macht mein Kollege.

Danke!

[Pikachu]

Welche CCSID (ID des codierten Zeichensatzes) haben die Ausgangsdatei (Befehl DSPFD) und ihre Felder (Befehl DSPFFD)?

[Mr-Ferret]

Beides mal CCSID 65535

[BenderD]

... das ist hex und wehrt sich gegen Konvertierung, aber...
wäre qsh cmd('system wrksyssts > myStreamfile') nicht einfacher?

D*B

[Fuerchau]

Du kannst auch die FROMCCSID(273) angeben, default ist *FILE und Binärfelder (65535) werden eben binär übertragen.

[Mr-Ferret]

Ich habs gewusst! ! ! Hier wird einem (mir) geholfen vielen Dank! ! ! mit FROMCCSID(273) funktioniert es. :-)
@BenderD mit dem Befehl erhalte ich die gleich Ausgabe (Datensalat)

Danke noch mal an alles und ein schönes Wochenende!

[Rainer Ross]

Hallo,

ab 7.1 geht das auch mit SQL

SELECT * FROM QSYS2.SYSTEM_STATUS_INFO; 

https://www.ibm.com/developerworks/c...EM_STATUS_INFO

Herzliche Grüße

Rainer

www.myhofi.com - powered by IBM i

[Fuerchau]

Wenn SQL dann auch noch gleich den Datenexport (ohne Programm) mit erledigt...

[Rainer Ross]

Wenn SQL dann auch noch gleich den Datenexport (ohne Programm) mit erledigt...

Ganz ohne Programm geht es über eine SQL-Function, aber es geht auch mit RPG

         ctl-opt dftactgrp(*no) option(*nounref);
      //------------------------------------------------------------------//
      //                                                                  //
      // WRKSYSSTS mit SQL ins IFS                                        //
      //                                                                  //
      //-----------------                                                 //
      // R.Ross 04.2016 *                                                 //
      //------------------------------------------------------------------//
      // Ausführungsbestimmungen                                          //
      //------------------------------------------------------------------//

           wrksyssts('/tmp/wrksyssts.xml');

           *inlr = *on;
      //------------------------------------------------------------------//
      // Procedure - wrksyssts                                            //
      //------------------------------------------------------------------//
         dcl-proc wrksyssts;
         dcl-pi *n;
                 file        varchar(256) const options(*varsize:*trim);
         end-pi;

         dcl-s   clob        sqltype(xml_clob_File);  // XML-CLOB-File

           exec sql set option datfmt=*iso, timfmt=*iso, commit=*none,
                    closqlcsr=*endactgrp;                  

           clob_name = file;                          // StreamFile
           clob_nl   = %len(%trim(clob_name));        // NameLength
           clob_fo   = SQFOVR;                        // FileOverwrite

           exec sql declare sqlcursor cursor for      // Declare Cursor
             select xmlserialize(
               content xmlelement(
                 name "row",
                   xmlforest(
                    ACTIVE_JOBS_IN_SYSTEM,  
                    AVERAGE_CPU_UTILIZATION,
                    SYSTEM_ASP_STORAGE,     
                    SYSTEM_ASP_USED
                   )
               )
               as clob(1M) including xmldeclaration)                            
             from QSYS2.SYSTEM_STATUS_INFO;

           exec sql open sqlcursor;                   // Open Cursor

           if sqlcod = *zero;
              exec sql fetch sqlcursor into :clob;
           endif;

           exec sql close sqlcursor;                  // Close Cursor

         end-proc;
      //------------------------------------------------------------------// 

Das Ergebnis ist eine XML-Datei, die so aussieht und mit PHP eingelesen werden kann

<?xml version="1.0" encoding="UTF-8"?>
<row>
    <ACTIVE_JOBS_IN_SYSTEM>244</ACTIVE_JOBS_IN_SYSTEM>
    <AVERAGE_CPU_UTILIZATION>2,11</AVERAGE_CPU_UTILIZATION>
    <SYSTEM_ASP_STORAGE>1702770</SYSTEM_ASP_STORAGE>
    <SYSTEM_ASP_USED>15,57</SYSTEM_ASP_USED>
</row>

Einlesen der Datei mit PHP

<?php
$xml = simplexml_load_file("wrksyssts.xml") or die("Error: Cannot create object");
print_r($xml);
?>

Das Ergebnis ist ein PHP-Array

SimpleXMLElement Object (
[ACTIVE_JOBS_IN_SYSTEM] => 244 
[AVERAGE_CPU_UTILIZATION] => 2,11
[SYSTEM_ASP_STORAGE] => 1702770  
[SYSTEM_ASP_USED] => 15,57) 

Die Feldnamen findet Ihr hier https://www.ibm.com/developerworks/c...EM_STATUS_INFO

Grafische Auswertungen mit der IBM i + www.webix.com + www.highcharts.com sehen so aus
www.myhofi.com/devhtm/charts.htm

Herzliche Grüße

Rainer