Das ist ein Schritt zuviel!

In dem folgenden Beispiel werden 3 Texte (nacheinander) direkt in eine IFS-Datei geschrieben.
Der Trick ist, dass die File Operation LocClobFile_FO richtig gesetzt wird.
SQFOVR generiert eine neue IFS-Datei oder überschreibt eine vorhandene IFS-Datei
SQLFAPP generiert eine neue IFS-Datei, sofern nicht vorhanden. Sofern die IFS-Datei vorhanden ist, werden die Daten ans Ende der IFS-Datei angefügt.

Code:
   DCL-S LocClobFile SQLTYPE(Clob_File) CCSID(1208);                                      
   DCL-S LocText     Char(50);                                                
   DCL-S LocIndex    Uns(3);                                                  
 //---------------------------------------------------------------------------
                                                                              
   Clear LocClobFile;                                                         
                                                                              
   LocClobFile_Name = '/home/Dir1/Dir2/YourIFSFile.txt';                                      
   LocClobFile_NL   = %Len(%Trim(LocClobFile_Name));                          
   LocClobFile_FO   = SQFOVR;       //Create/Override existing IFS File       
                                                                              
   For LocIndex = 1 to 3;                                                     
       Select;                                                                
       When LocIndex = 1;                                                     
            LocText  = 'The important thing is not to stop questionning';     
       When LocIndex = 2;                                                     
            LocText  = 'Curiosity has its own reason for existence';          
       When LocIndex = 3;                                                     
            LocText  = 'Quote: Albert Einstein';                              
       EndSl;                                                                 
                                                                              
       Exec SQL Set :LocClobFile = :LocText;                                  
       LocClobFile_FO   = SQFAPP;      //Add Data                             
   EndFor;
Birgitta