API QCLSCAN

[Fuerchau]

Das ist genau das Problem. QCLSCAN kann es nicht lösen, da der Schalter, wie gesagt, nicht die Suchzeichen sondern die zu durchsuchende Zeichenkette umwandelt (siehe Beschreibung).
Ist der Suchbegriff also in GrossKlein muss ich ihn vorher mit QDCXLATE in Grossbuchstaben wandeln.
Ansonsten wäre SQL besser:

where ... upper(mydbfield) like upper(trim(:myfield)) ...

[B.Hauser]

Man könnte sich auch mit einer kleinen RPG-Prozedur mit embedded SQL behelfen:

Die folgende Prozedur bringt *Zeros zurück, wenn der übergebene String nicht gefunden wurde. Ansonsten wird die erste Position an der der Such-String steht zurückgegeben.
Groß- und Kleinschreibung wird dabei ignoriert, d.h. wenn nach 'Dagobert Duck' gesucht wird, wird sowohl 'DAGOBERT DUCK' als auch 'dAgObErT dUcK' gefunden:

P ScanLangIdShr   B                   Export                 
                                                             
D ScanLangIdShr   PI            10I 0                        
D   PPText                   32740A   varying  Const         
D   PPSearch                 32740A   varying  Const         
                                                             
D  Position       S             10I 0                        
 *-------------------------------------------------------
C/EXEC SQL  Set Option SrtSeq = *LangIdShr                   
C/End-EXEC                                                   
                                                             
C/EXEC SQL  Set :Position = PosStr(:PPText, :PPSearch)       
C/End-EXEC                                                   
                                                             
C                   Return    Position                       
P ScanLangIdShr   E 

Birgitta

[Fuerchau]

PosStr ist aber leider nicht so flexibel, da QCLSCAN auch Wildcards unterstützt. Like gibt da auch leider keine Position zurück, hat aber wiederum Wildcards.

[B.Hauser]

Ob ich LIKE oder POSSTR verwende ist im Endeffekt egal!

Mit Like (inclusive Wildcards und unter Berücksichtigung der Sonderzeichen % und _) würde die Funktion wie folgt aussehen:

P Like            B                   Export

D Like            PI              A
D   PPText                   32740A   varying  Const 
D   PPSearch                 32740A   varying  Const 
D   PPEscape                     1A            Const Options(*NoPass)  

D ParmEscape      C                   const(3) 

D  Found          S              1A                                        
 *----------------------------------------------------------
C/EXEC SQL  Set Option SrtSeq = *LangIdShr                    
C/End-EXEC                                                    

C                   If        %Parms >= ParmEscape
C/EXEC SQL
C+ Set :Found    =  Case when :PPText like :PPSearch escape :PPEscape
C+                       then '1' else '0' End
C/END-EXEC
C                   else
C/EXEC SQL
C+ Set :Found    =  Case when :PPText like :PPSearch
C+                       then '1' else '0' End
C/END-EXEC
C                   EndIf

C                   Return    Found
P Like            E 

Birgitta

[TARASIK]

Hallo Birgitta und Fuerchau,
vielen Dank an Euch beide. Es funktioniert jetzt.